P11-ExponentialWordProblems.mws

High School Modules > Precalculus by Gregory A. Moore

     Exponential Growth & Decay Word Problems



Delving into the world of exponetial growth and decay word problems.

[Directions : Execute the Code Resource section first. Although there will be no output immediately, these definitions are used later in this worksheet.]

  0. Code

>    restart; with(plots): 

Warning, the name changecoords has been redefined

>    merge := proc( a1,a2,a3, b1,b2,b3,k,n)
local c;
c := COLOR(RGB, a1 + k*(b1-a1)/n,
                a2 + k*(b2-a2)/n,
                a3 + k*(b3-a3)/n );
return c;
end:

>    ShadedPlot := proc( f)
   display( [seq( plot( k*f(x), x = -1..5, filled = true,
             color = merge(.15,.15,.15,.7,.7,.7,k,10)), k = 0..10 )] );
end proc:

>    ShadedPlotR := proc( f)
   display( [seq( plot( k*f(x), x = -1..5, filled = true,
             color = merge(1,.1,.1,1,.5,.5,k,10)), k = 0..10 )] );
end proc:

>    ShadedPlotG := proc( f)
   display( [seq( plot( k*f(x), x = -1..5, filled = true,
             color = merge( .3,.8,.2, .7,.9,.6,k,10)), k = 0..10 )] );
end proc:

>    ShadedPlotB := proc( f)
   display( [seq( plot( k*f(x), x = -1..5, filled = true,
             color = merge(.15,.15, .8, .6,.6, .8,k,10)), k = 0..10 )] );
end proc:

  1. Growth and Decay


First, let's just catch a glimpse of what exponential growth and decay looks like. Here is a family of exponential functions with the same growth rate, but differing initial values ( C = 10, 20 , 30, ..., 100).

>    ShadedPlotB( 10*exp(x/5) );

[Maple Plot]

>    plot( { 10*k*exp(x/5) $ k = 1..10}, x = -4..4, y = 0..250,
title=`Exponential Growth - Different Initial Values`);

[Maple Plot]




Decreasing exponential functions look like this.( C = 10, 20 , 30, ..., 100).

>    ShadedPlotR( 10*exp(-x/5) );

[Maple Plot]


Here is a family of exponential functions with the same initial value (C), but differing growth rates (1/5, 2/5, 3/5,...,2). Note that all of these functions are increasing.

>     plot( { 10*exp(x*k/5) $ k = 1..10}, x = 0..4, y = 0..100,
title=`Exponential Growth - Different Growth Rates`);

[Maple Plot]

This family has differing decay rates. Note that these functions are all decreasing.

>    plot( { 10*exp(-x*k/5) $ k = 1..10}, x = 0..10,
title=`Exponential Decay - Different Decay Rates`);

[Maple Plot]

In this single diagram we can see both growing (increasing) and decaying (decreasing) exponential functions.

>    plots[display]([
    plot( 100*exp(abs(x)/20) , x = -20..20, filled = true,
         color = COLOR(RGB, .8,.8,.8)),          
    plot(  { 100*exp(x*k/200) $ k = 0..10}, x = -20..20,
               color = COLOR(RGB, .2, .3, 1),            
            title= `Red = Decay and Blue = Growth , `),
 plot( { 100*exp(-x*k/200) $ k = 1..10}, x = -20..20,
               color = COLOR(RGB, 1,.3,.1) )]);

[Maple Plot]



Here are some more intensive plots. If you have little RAM or a slower processor,please skip these.

>    plots[display]([
  seq( plot( exp(x*k/20), x = 0..8, filled = true,
             color = merge(.1,.1,.8, .5,.5,.8,k,10)), k = 0..10 ),
 seq( plot( exp(-x*k/20), x = -8..0, filled = true,
             color = merge(.8,.1,.1, .8,.5,.5,k,10)), k = 0..10 ),
 seq( plot( exp(-abs(x)*k/20), x = -8..8, filled = true,
             color = merge(.45,.1,.45,.65,.5,.65,k,10)), k = 0..10 )
 ]);

[Maple Plot]

>    A := seq( plot( exp(x*k/30), x = 0..4, filled = true,
             color = merge(.4,.4, 1, .8,.8,1 ,k,10)), k = 0..10 ):
B :=     plot( 1, x = 0..4, filled = true,
             color = COLOR(RGB, .4,.4,.4) ):

C := seq( plot( exp(-x*(10-k)/20), x = 0..4, filled = true,
             color = merge( 1,.8,.8, 1,.2,.2,k,10)), k = 0..9 ):

>    plots[display]([C,B,A]);

[Maple Plot]


 

  2. Population Growth Examples


All basic exponential growth and decay problems use the formula f(t) = C*exp(kt) .
We use the given information to solve for the constants C and k, then solve the rest of the problem.

           Example 2.1  :  A population begins with 1,200 at time t = 0, and grows exponentially, until it reaches
                               3,500 at time t = 9.

                A.   Find a simplified function which expresses the size of the population at time t.
                B.   What is the size at t = 36?
                C.   At what time does the population reach 100,000?

 

>     restart;

>     f := t -> C*exp(k*t);

f := proc (t) options operator, arrow; C*exp(k*t) end proc

>     1200 = f(0); solve(%, { C } ); assign( % ); f(t);

1200 = C

{C = 1200}

1200*exp(k*t)

>     3500 = f(9); solve( %, { k }); assign( % ); simplify( f(t), exp);

3500 = 1200*exp(9*k)

{k = 1/9*ln(35/12)}

1200*(35/12)^(1/9*t)

>     f(36);  evalf(%);

37515625/432

86841.72454

>     solve( 100000 = f(t)); evalf(%);

9*ln(250/3)/ln(35/12)

37.18618994


           Example 2.2  :  A population begins with 2,500 at time t = 2 and grows exponentially until it reaches
                                   6,000 at time t = 7

                A.   Find a simplified function which expresses the size of the population at time t.
                B.   What is the size at t = 12?
                C.   What is the size at t = 20?


>    restart:

>    f := t -> C*exp(k*t);

f := proc (t) options operator, arrow; C*exp(k*t) end proc

>    solve( f(2) = 2500, {C} );    assign(%);   f(t);

{C = 2500/exp(2*k)}

2500/exp(2*k)*exp(k*t)

>    solve( f(7) = 6000, {k} );    assign(%);   simplify( f(t), exp );

{k = -1/5*ln(5/12)}

625/3*5^(2/5)*12^(3/5)*(5/12)^(-1/5*t)

>    f(12);

14400

>    f(20); evalf(%);

6912*5^(2/5)*12^(3/5)

58438.69094

 

  3. Percentage Growth Examples


           Example 3.1  :  A population begins with 35,000 at time t = 0, and grows exponentially at 6% per year.

                A.   Find a simplified function which expresses the size of the population at time t.
                B.   What is the size at t = 8?

>    restart;

>    f := t -> C*exp(k*t);

f := proc (t) options operator, arrow; C*exp(k*t) end proc

>    solve( f(0) = 35000, {C} );
assign(%);     
f(t);

{C = 35000}

35000*exp(k*t)

>    f(1) = 1.06*f(0);
solve( %, {k});
assign(%);

35000*exp(k) = 37100.00

{k = .5826890812e-1}

>    f(t);

35000*exp(.5826890812e-1*t)

>    f(8);

55784.68262




          Example 3.1  :  A population begins with 432,000 at time t = 0 and grows exponentially until it reaches
                                  511,000 at time t = 3. Find the annual growth rate.

>    restart;   
f := t -> C*exp(k*t);

f := proc (t) options operator, arrow; C*exp(k*t) end proc

>    f(0) = 432000;
solve( %, {C}); assign(%);  f(t);

C = 432000

{C = 432000}

432000*exp(k*t)

>    f(3) = 511000;
solve( %, {k}); assign(%);  f(t);

432000*exp(3*k) = 511000

{k = 1/3*ln(511/432)}

432000*exp(1/3*ln(511/432)*t)

>    simplify(%, exp);

432000*(511/432)^(1/3*t)

>    (% - 1)*100;

43200000*(511/432)^(1/3*t)-100

>    evalf( f(1)/f(0) );

1.057577943


  4. Cooling Law Example


       Example 4.1  :  Using Newtons law of cooling, an object brought into a room of T[0]  degrees will have this temperature at time t :  T(t) = T[0]+C*exp(k*t) .  An       object at 48 degrees is brought into a room of 32 degrees,
      and is 42 degrees at time t = 10

                A.   Find a simplified formula for the temperature of this object at time t
                B.   Find at what time the object will reach 35 degrees.
                C.   Find the temperature at t = 200.
                D.   Plot the graph of this function.

>    restart;

>    T := t -> T0 + C*exp(k*t);

T := proc (t) options operator, arrow; T0+C*exp(k*t) end proc

>    T0 := 32; T(t);

T0 := 32

32+C*exp(k*t)

>    T(0) = 48; solve(%, {C});  
assign(%);   T(t);

32+C = 48

{C = 16}

32+16*exp(k*t)

>    T(10) = 42;   
solve(%, {k});  
assign(%);   
simplify(T(t), exp);
 

32+16*exp(10*k) = 42

{k = 1/10*ln(5/8)}

32+16*(5/8)^(1/10*t)

>    solve( T(x) = 35, x);
evalf(%);

10*ln(3/16)/ln(5/8)

35.61624485

>    T(200); evalf(%);

2305938376645334577/72057594037927936

32.00132349

>    plot( {T(x), T0}, x = 0..20, y = 0..(T0+C));

[Maple Plot]

  5. Half-Life Example


One particular type of exponential decay problem involves the half-life of a radioactive material. The half life is the time period for half of the material to decay.

The half-life is the solution to the equation : f(t) = f(0)/2 .


         Example 5.1  :  Each year, 15% of a material decays. Find the half-life of this material.

>    restart;

>    f := t -> N*.85^(t);

f := proc (t) options operator, arrow; N*.85^t end proc

>    HL := solve( f(t) = (1/2)*f(0), t);

HL := 4.265024282


We can view the effect of the half-life in this example of an exponential decay function.

>    with(plots): N := 100:  
 

Warning, the name changecoords has been redefined

>    display(plot( {100, seq(  [[HL*2^(k-1) ,0],[HL*2^(k-1), f(0)]] ,
           k = 1..5),
          seq(  [[0 ,f(HL*2^(k-1))],[N, f(HL*2^(k-1))]] , k = 1..5)},
            x = 0..N, color = green),    
          plot( f(x), x = 0..N, title=`half-life`, color = blue)  );

[Maple Plot]

Note that each vertical line is half as high the previous, and each horizontal line is twice as large.

     Example 4.2  :  A substance has a half-life of 200 years. How much will be left in 75 years if you start with 3000 tons?

>    restart;

>    f := t -> C*exp(k*t);

f := proc (t) options operator, arrow; C*exp(k*t) end proc

>    assign( C= 3000);

>    f(200) = (1/2)*f(0);

3000*exp(200*k) = 1500

>    k = solve( %, k);  
assign(%);
f(t);

k = -1/200*ln(2)

3000*exp(-1/200*ln(2)*t)

>    f(75);
evalf(%,5);

1500*2^(5/8)

2313.3

>   


        © 2002 Waterloo Maple Inc