P08-ComplexPowers.html

High School Modules > Precalculus by Gregory A. Moore

Powers of Complex Numbers & DeMoivre's Formula

This is a further development of complex powers. Also see worksheets on Complex Numbers and Complex Number Operations in the Algebra I & II PowerTool.

[Directions : Execute the Code Resource section first. Although there will be no output immediately, these definitions are used later in this worksheet.]

0. Code

> restart; with(plots):

Warning, the name changecoords has been redefined

>    ComplexPlot := proc()
   local k,A,Pt,c,cg,shade,r,u,Lines;
   u:= 0;
   cg := COLOR(RGB, .7,.8,.7);
   for k from 1 to nargs do
       shade := evalf(rand()/10^12,2)/4 + .3;
       c := COLOR(RGB, shade,shade+.2, shade);
       A||k := complexplot( [0,args[k]], linestyle = 2, scaling = constrained,
                            color = c);
       Lines||k := plot( [[ 0, Im(args[k])], [Re(args[k]), Im(args[k])],
                          [Re(args[k]), 0]], color = cg);

       u := max( u, abs(Re(args[k])),abs(Im(args[k])) );
   od;

   r := evalf(u/40,2);
   for k from 1 to nargs do
       shade := evalf(rand()/10^12,2)/4 + .1;
       c := COLOR(RGB, shade,.8, shade);
       Pt||k := plottools[disk]( [Re(args[k]), Im(args[k])],r,
                           color = c ); od;

  display( [seq( A||k, k = 1..nargs), seq( Pt||k, k = 1..nargs),
            seq( Lines||k, k = 1..nargs)] );
end proc:

>

1. Complex Products

Here are two complex numbers and their geometric representation.

> z := 2 + I; w := -1 + 3*I;

> ComplexPlot(z,w);

Now, here are the same two numbers together with their product. (Maple scales the picture to fit, which results in a 'zoomed out' view.)

> z*w;

> ComplexPlot(z,w, z*w );

Apparently the product is both longer and at a different angle than the two original numbers. At first guess, it appears both the length and angle increases. Lets look at some more examples.

> z := -5 + I; w := 3 + 2*I;
z*w;
ComplexPlot(z,w, z*w );

> z := -2 + 3*I; w := 3 - 2*I;
z*w;
ComplexPlot(z,w, z*w );

> z := 5*I; w := 4+4*I;
z*w;
ComplexPlot(z,w, z*w );

Actualy there is some logic to this situation. Lets look at the arguments and absolute values of the numbers and their product.

> z1 := 2 + 3*I;
z2 := 5 + 1*I;
z*w;
ComplexPlot(z,w, z*w );

The absolute value is the product is the product of the absolute values.

> a1 := abs(z1);
a2 := evalf(abs(z2));
a3 := abs(z1*z2);
a1 * a2;

The argument of a product is the sum of the arguments of the factors.

> theta||1 := evalf(argument(z1));
theta||2 := evalf(argument(z2));
theta := argument(z1*z2);
theta||1 + theta||2;

Here is an example where its easy to see that product of absolute values is the absolute value of the product.

> z1 := 3 + 4*I; abs(z1);
z2 := 12 + 5*I; abs(z2);
z1*z2;
abs(z1*z2);
ComplexPlot( z1,z2, z1*z2);

>

2. Powers of Complex Numbers

Complex Powers

Taking the power of any number, variable, expression, or complex number simply involves repeated multiplication. So the same principles will apply.

> (3 + 2*x)^3;
% = expand(%);

> (3 + 2*I)^3;

Note that 46 = 54 - 8, and -9 = 27 - 36. Can you explain this?

Here is the geometric view of the first four powers of a complex number. The powers are "rotating" to the left, in a counter-clockwise direction. Notice that in some cases the absolute value of the powers is getting bigger or smaller, faster or slower.

> z := 1.2 + .9*I;
ComplexPlot( z, z^2, z^3, z^4, z^5, z^6);

> z := .6 + .5*I;
ComplexPlot( z, z^2, z^3, z^4);

> z := 2 + 1*I;
ComplexPlot( z, z^2, z^3, z^4);

Also, it's possible for the powers to stay on the unit circle. This happens if the original number has absolute value of 1.

> z := sqrt(3)/2 + I/2;
display( polarplot( 1, color = gray), ComplexPlot( seq(z^k, k = 1..11) ));

3. De Moivre's Formula

Just as with real numbers or variables, powers are simply repeated multiplication of the same factor.

> (3 + 2*I)^10;

> (-1/3 + (1/4)*I)^10;

However, when a complex number is in trig form, we can apply this useful formula by the Marquis De Moivre.

> z:='z': r:='r': theta:='theta':

> demoivre :=
z^n = (r^n)*( cos(n*theta) + I*sin(n*theta) );

Given a complex number in polar form, we can compute the power much faster by raising the modulus (or absolute value, which is a real number) to the power, and then multiplying the angle by the power and computing the resulting sine and cosine.

Example :

A problem tailor made for this formula! We can get Maple to give us the result. However, this would be quite difficult to expand and compute without a calculator or computer because of the unusual angle.

> z := 2*( cos( Pi/7) + I*sin(Pi/7) );
z^14: % = evalc(%); evalf(%);

Lets allow the formula to work its magic.

> 2^14; (Pi/7)*14;

> result = 16384* (cos( 2*Pi) + I*sin( 2*Pi));

What if we are not so lucky as to be given a number in this form? Convert it, and then use the formula, of course!

Example :

Of course, Maple can do the dirty work for us, ....

> z := 3 - 3*I;
z^12;

... but if we were stranded on a desert isle and needed to do this without the tools of modern life, it would be quite tedious to multiply it out. In fact, we would need quite a few papryus scratch husks to write on. We'll convert the form and use the formula.

> r := abs(z);
theta := arctan( Im(z)/Re(z));

> z = r*('cos'(theta) + I*'sin'(theta));

Now that we have expressed z in polar form, we can plug into the formula. The main part is to compute and , then evaluate the result using those values.