P05-ComplexNumbers.mws

High School Modules > Precalculus by Gregory A. Moore

     The Polar & Exponential Form of Complex Numbers


This is a further development of complex numbers. Also see worksheets on Complex Numbers and Complex Number Operations in the Algebra I & II PowerTool.

[Directions : Execute the Code Resource section first. Although there will be no output immediately, these definitions are used later in this worksheet.]

  0. Code

>    restart; with(plots): 

Warning, the name changecoords has been redefined

>    ComplexPlot  :=  proc()
   local k,A,Pt,c,cg,shade,r,u,Lines;
   u:= 0;
   cg := COLOR(RGB, .7,.8,.7);
   for k from 1 to nargs do
       shade := evalf(rand()/10^12,2)/4 + .3;
       c := COLOR(RGB, shade,shade+.2, shade);  
       A||k := complexplot( [0,args[k]], linestyle = 2, scaling = constrained,
                            color = c);
       Lines||k := plot( [[ 0, Im(args[k])], [Re(args[k]), Im(args[k])],
                          [Re(args[k]), 0]], color = cg);

       u := max( u, abs(Re(args[k])),abs(Im(args[k])) );
   od;

   r := evalf(u/40,2);
   for k from 1 to nargs do
       shade := evalf(rand()/10^12,2)/4 + .1;
       c := COLOR(RGB, shade,.8, shade);
       Pt||k := plottools[disk]( [Re(args[k]), Im(args[k])],r,
                           color = c ); od;

  display( [seq( A||k, k = 1..nargs),  seq( Pt||k, k = 1..nargs),
            seq( Lines||k, k = 1..nargs)] );
end proc:

>    reset := proc()
global a,b,z,R,theta;
a := 'a': b := 'b':  z := 'z': theta := 'theta': R := 'R':
return (a,b,z,R,theta):
end proc:

  1. The Polar Form of Complex Numbers


     Concept of Polar Form

Here is a complex number in standard "real part + imaginary part" component form.

>    z :=  4 + 4*sqrt(3)*I;   

z := 4+4*I*3^(1/2)

>    ComplexPlot(z);

[Maple Plot]



When we look at the geometric representation, we might notice that this point forms a right triangle by looking at the real part of the number on the x-axis as one leg, and the diagonal line from the origin to the point as the hypotenuse. The angle that the hypotenuse makes with the x axis is called the argument of the complex number.

>    argument(z);

1/3*Pi


And the distance from the origin to the point is the absolute value of the complex number.

>    abs(z);

8


These two numbers can identify the point completely. For example, this same number can be expressed in this form - which is called the polar or trigonometric form.

>    8*cos(Pi/3) + 8*sin(Pi/3)*I;

4+4*I*3^(1/2)

  2. Converting To Polar Form


  Converting from Component Form to Trig Form

As above, the process involves finding two things :
               - the argument and
               - the modulus.


                  Finding the Argument

We can compute the argument directly using Maple, but to do it by hand, we would use the two legs of the triangle to find the slope. Those two legs are none other than the real and imaginary parts of the complex number. Once we know the slope, we note that it is equal to the tangent of the angle. Therefore the inverse tangent of the slope is the angle.

>    z := 11 + 11*I;
arctan( Im(z) / Re(z) );
argument(z);

z := 11+11*I

1/4*Pi

1/4*Pi

>    z := 4*sqrt(3) -  4*I;
arctan( Im(z) / Re(z) );
argument(z);

z := 4*3^(1/2)-4*I

-1/6*Pi

-1/6*Pi


Something seems to go wrong here.

>    z := -5 + 5*sqrt(3)*I;
arctan( Im(z) / Re(z) );
argument(z);

z := -5+5*I*3^(1/2)

-1/3*Pi

2/3*Pi


 What happened? Well, the range of the arctan is [-Pi/2, Pi/2]  which is only quadrants I and IV. However, this point is actually in quadrant II. So if we add Pi  to our arctan, we get the actual argument of 2*Pi/3 . Here is another example.

>    z := - 10*sqrt(3)  + 10*I;arctan( Im(z) / Re(z) );
argument(z);

z := -10*3^(1/2)+10*I

-1/6*Pi

5/6*Pi

 

                Finding the Absolute Value


The absolute value of a complex number is essentially Pythagoras' theorem. We know the legs of the triangle to be the real and imaginary parts of the complex number.

>    z := 9 + 40*I;

z := 9+40*I

>    a := Re(z);
b := Im(z);
c^2 = a^2 + b^2;
c = sqrt(a^2 + b^2);

a := 9

b := 40

c^2 = 1681

c = 41

>    sqrt( Re(z)^2 + Im(z)^2);

41

>    abs(z);

41

>    z := -15 + 8*I;
abs(z);

z := -15+8*I

17

>    z := -2 + 1*I;
abs(z);

z := -2+I

5^(1/2)


               Expressing a Complex Number in Polar Form


Once you know the argument and absolute value, then just write it in the form :
               z = R*(cos(theta)+I*sin(theta))
where R = |z|, and theta = arg(z) .
 
    

>    z := -12 + 12*I;

z := -12+12*I

>    theta := argument(z);

theta := 3/4*Pi

>    R := abs(z);

R := 12*2^(1/2)

>    z = R * ('cos'(theta) + I*'sin'(theta));

-12+12*I = 12*2^(1/2)*(cos(3/4*Pi)+sin(3/4*Pi)*I)

>    z := 9 -40*I;
theta := argument(z);
R := abs(z);
z = R * ('cos'(theta) + I*'sin'(theta));

z := 9-40*I

theta := -arctan(40/9)

R := 41

9-40*I = 41*cos(-arctan(40/9))+41*I*sin(-arctan(40/9))

>    z := sqrt(39) + sqrt(13)*I;
theta := argument(z);
theta := simplify(%);
R := abs(z);
z = R * ('cos'(theta) + I*'sin'(theta));

z := 39^(1/2)+13^(1/2)*I

theta := arctan(1/39*13^(1/2)*39^(1/2))

theta := 1/6*Pi

R := 2*13^(1/2)

39^(1/2)+13^(1/2)*I = 2*13^(1/2)*(cos(1/6*Pi)+sin(1/6*Pi)*I)


 

  3. Converting from Polar Form


        Converting from Trig Form to Component Form



It's even easier to convert from trig form to component form.

>    reset():

>    theta := 4*Pi/3;
R := 60;
z = R * ('cos'(theta) + I*'sin'(theta));

theta := 4/3*Pi

R := 60

z = 60*cos(4/3*Pi)+60*I*sin(4/3*Pi)

>    a := R*cos(theta);
b := R*sin(theta);
z = a + b*I;

a := -30

b := -30*3^(1/2)

z = -30-30*I*3^(1/2)

>    theta := Pi/8;
R := 256;
z = R * ('cos'(theta) + I*'sin'(theta));
a := R*cos(theta);
b := R*sin(theta);
z = a + b*I;
evalf(%);

theta := 1/8*Pi

R := 256

z = 256*cos(1/8*Pi)+256*I*sin(1/8*Pi)

a := 256*cos(1/8*Pi)

b := 256*sin(1/8*Pi)

z = 256*cos(1/8*Pi)+256*I*sin(1/8*Pi)

z = 236.5131603+97.96695872*I

>    theta := 1;
R := 10;
z = R * ('cos'(theta) + I*'sin'(theta));
a := R*cos(theta);
b := R*sin(theta);
z = a + b*I;
evalf(%);

theta := 1

R := 10

z = 10*cos(1)+10*I*sin(1)

a := 10*cos(1)

b := 10*sin(1)

z = 10*cos(1)+10*I*sin(1)

z = 5.403023059+8.414709848*I


 

  4. The Exponential Form of Complex Numbers


     e to an imaginary Power

Euler discovered that e, when raised to an imaginary power, can be expressed as a complex number in polar form. Obviously a revolutionary discovery made using Taylor series, which you will learn about in calculus.

>    reset();

a, b, z, R, theta

>    exp(theta*I):
% =  convert(%, trig);

exp(theta*I) = cos(theta)+sin(theta)*I


Here are examples

>    ''exp( (7*Pi/6)*I)'':
% =  convert(%, trig);

exp(7/6*I*Pi) = -1/2*3^(1/2)-1/2*I

>    ''exp( (2.75)*I)'':
% =  convert(%, trig);

exp(2.75*I) = -.9243023786+.3816609921*I


The absolute value of e^(i*theta)  for any value of theta  is 1, and all such numbers lie on the unit circle. theta  can be any real number.

>    exp( (7*Pi/6)*I):  z1 := convert(%, trig);
exp( (2.75)*I):    z2 := convert(%, trig);
exp( 1*I):         z3 := convert(%, trig);
exp( sqrt(2)*I):   z4 := convert(%, trig);
exp( (-4/7)*I):    z5 := convert(%, trig);

z1 := -1/2*3^(1/2)-1/2*I

z2 := -.9243023786+.3816609921*I

z3 := cos(1)+sin(1)*I

z4 := cos(2^(1/2))+sin(2^(1/2))*I

z5 := cos(4/7)-I*sin(4/7)

>    abs(z1);   abs(z2);   
abs(z3): % = simplify(%);
abs(z4): % = simplify(%);
abs(z5): % = simplify(%);

1

1.000000000

(cos(1)^2+sin(1)^2)^(1/2) = 1

(cos(2^(1/2))^2+sin(2^(1/2))^2)^(1/2) = 1

(cos(4/7)^2+sin(4/7)^2)^(1/2) = 1

>    display( polarplot( 1, color = gray),
         ComplexPlot( z1,z2,z3,z4,z5));

[Maple Plot]




       e to a Complex Power

Although this might seem to be much more complicated, it really isn't because of one of the simplest rules of exponents.

>    exp(a+b) = exp(a) * exp(b);

exp(a+b) = exp(a)*exp(b)

>    exp(a+I*b) = exp(a) * exp(I*b);

exp(a+b*I) = exp(a)*exp(b*I)


So it becomes a product of two numbers. e^a  is a real number, and e^(I*b)  is a polar form of a complex number that we saw just above.

>    exp( 3 + 2*I);

exp(3+2*I)

>    exp( 3 + 2*I ) = exp(3) * exp(2*I);

exp(3+2*I) = exp(3)*exp(2*I)

>    exp( 3 + 2*I ) = exp(3) * convert( exp(2*I), trig) ;

exp(3+2*I) = exp(3)*(cos(2)+sin(2)*I)


Here is another example.

>    exp( 5 + Pi*I ) = exp(5) * convert( exp(Pi*I), trig) ;

exp(5+Pi*I) = -exp(5)

>    exp( ln(8) + (3*Pi/4)*I ) =
         exp(ln(8)) * convert( exp((3*Pi/4)*I), trig) ;

exp(ln(8)+3/4*I*Pi) = -4*2^(1/2)+4*I*2^(1/2)

>    exp( 1 + 2*Pi*I ) = exp(1) * convert( exp(2*Pi*I), trig) ;

exp(1+2*I*Pi) = exp(1)


 

  5. Developing Trig Identities at Warp Speed


As you are probably well aware, trigonometry has no shortage of formulas and identities. Here are some hopefully familiar reminders.

>    sin(a + b):
% = expand(%, trig);

sin(a+b) = sin(a)*cos(b)+cos(a)*sin(b)

>    cos(a - b):
% = expand(%, trig);

cos(a-b) = cos(a)*cos(b)+sin(a)*sin(b)

>    tan(2*a):
% = expand(%, trig);

tan(2*a) = 2*tan(a)/(1-tan(a)^2)


These formulas are less easy to prove than they are to remember - using the geometry. However, they can be developed very quickly using the exponential form of complex numbers. What we do is express an exponential expression in two different ways, using the standard rules of exponents. Then we expand each side into polar forms, and equate the real and imaginary parts of each side.

>    exp( (a+b)*I):
L := %:
% = expand(%);
convert( %, trig):
convert( L, trig) = expand( rhs(%) );

exp((a+b)*I) = exp(a*I)*exp(b*I)

cos(a+b)+sin(a+b)*I = cos(a)*cos(b)+cos(a)*sin(b)*I+sin(a)*cos(b)*I-sin(a)*sin(b)

>    `Equate the real parts of the left and right sides`;
cos(a+b) = cos(a)*cos(b)-sin(a)*sin(b);

`Equate the real parts of the left and right sides`

cos(a+b) = cos(a)*cos(b)-sin(a)*sin(b)

>    `Equate the imaginary parts of the left and right sides`;
I*sin(a+b) = I*cos(a)*sin(b)+I*sin(a)*cos(b);
sin(a+b) = cos(a)*sin(b)+ sin(a)*cos(b);

`Equate the imaginery parts of the left and right sides`

sin(a+b)*I = cos(a)*sin(b)*I+sin(a)*cos(b)*I

sin(a+b) = sin(a)*cos(b)+cos(a)*sin(b)



Voila! You have just developed two trig identities for the price of one. You have a formula for the sine of a sum of angles, and a formula for the cosine of a sum. What formulas come out of these?

>    exp( 2*a*I):
L := %:
% = expand(%);
convert( %, trig):
convert( L, trig) = expand( rhs(%) );

exp(2*I*a) = exp(a*I)^2

cos(2*a)+sin(2*a)*I = cos(a)^2+2*I*cos(a)*sin(a)-sin(a)^2


You can even amaze your friends with your own identities "not in the book."

>    exp( 4*a*I):
L := %:
% = expand(%);
convert( %, trig):
convert( L, trig) = expand( rhs(%) );

exp(4*I*a) = exp(a*I)^4

cos(4*a)+sin(4*a)*I = cos(a)^4+4*I*cos(a)^3*sin(a)-6*cos(a)^2*sin(a)^2-4*I*cos(a)*sin(a)^3+sin(a)^4

>    exp( (2*a + b)*I):
L := %:
% = expand(%);
convert( %, trig):
convert( L, trig) = expand( rhs(%) );

exp((2*a+b)*I) = exp(a*I)^2*exp(b*I)

cos(2*a+b)+sin(2*a+b)*I = cos(a)^2*cos(b)+cos(a)^2*sin(b)*I+2*I*cos(a)*sin(a)*cos(b)-2*cos(a)*sin(a)*sin(b)-sin(a)^2*cos(b)-I*sin(a)^2*sin(b)
cos(2*a+b)+sin(2*a+b)*I = cos(a)^2*cos(b)+cos(a)^2*sin(b)*I+2*I*cos(a)*sin(a)*cos(b)-2*cos(a)*sin(a)*sin(b)-sin(a)^2*cos(b)-I*sin(a)^2*sin(b)

>    exp( (3*b)*I):
L := %:
% = expand(%);
convert( %, trig):
convert( L, trig) = expand( rhs(%) );

exp(3*I*b) = exp(b*I)^3

cos(3*b)+sin(3*b)*I = cos(b)^3+3*I*cos(b)^2*sin(b)-3*cos(b)*sin(b)^2-I*sin(b)^3


         © 2002 Waterloo Maple Inc