P02-SyntheticDivision.html

High School Modules > Precalculus by Gregory A. Moore

Synthetic Division

Developing the method of synthetic division of polynomials.

[Directions : Execute the Code Resource section first. Although there will be no output immediately, these definitions are used later in this worksheet.]

0. Code

> restart;

>    PolyDivide := proc(S,T)
    local Q,R;
    Q := quo( S, T, x, 'R'):
    print(S/T = Q + R/T);
    end proc:

>    LongDiv := proc( P, r)
     local A, C, d, i,j,k,cols,rows,q,L2,dg, Q,R;
    d := degree( P);    cols := d + 3; rows := 3*d + 3;
    for k from 0 to d do     C||k := coeff(P, x, k) ; od;
    A := array( [seq( [ seq(` `, j = 1..cols ) ],   i = 1..rows) ]);

    A[3,1] := x-r;
    for k from 0 to d do A[3,d - k + 3] := C||k*x^k ; od;
    for k from 0 to d do A[2,d - k + 3] := `__`; od;
    A[k,2] := `|`;

    for k from 1 to d do
      q := simplify(A[3*k,2+k]/x); A[1,2+k] := q;
      A[1+3*k,1] := A[3,1]* q;   A[1+3*k,2] := ` = `;
      L2 := expand(A[3,1]*q);   dg := degree(L2);
      A[1+3*k,2+k] := coeff(L2, x, dg)   *x^dg;
      A[1+3*k,3+k] := coeff(L2, x, dg-1) *x^(dg-1);
      if (k > 1) then A[3*k,3+k] := A[3,3+k]; fi;
      for j from k+2 to k+3 do A[2+3*k,j] := `__`; od;
      A[3 + 3*k,2+k] := A[3*k,2+k] - A[1+3*k,2+k];
      A[3 + 3*k,3+k] := A[3*k,3+k] - A[1+3*k,3+k];
    od;
    print(A);
    Q := quo( P , (x-r), x, 'R'):
    print(` `);print(` `);
    print(P/(x+r) = Q + R/(x+r));print(` `);
    end proc:

>    SynDiv := proc( P, r)
    local A, C, d, i,j,k;
    d := degree( P);
    for k from 0 to d do   C||k := coeff(P, x, k) ; od;
    A := array( [seq( [ seq(` `, j = 0..(d+2) ) ],   i = 1..4) ]);
    A[1,1] := r;
    for k from 0 to d do A[1,d - k + 3] := C||k ; od;
    for k from 0 to d do A[2,d - k + 3] := 0; od;
    for k from 0 to d do A[3,d - k + 3] := `__`; od;
    for k from 0 to d do
       A[4,k + 3] := A[1,k + 3] + A[2,k + 3];
       if(k<d) then A[2,k + 4] := r * A[4,k + 3]; fi
        od;
    print(A);
    end proc:

>

1. Long Division of Polynomials

We know how to divide polynomials by long division.

> LongDiv( x^2 + 5*x + 2, -3 );

> LongDiv( x^3 - 4*x^2 + 3*x + 7, + 2 );

Now Lets find a slicker way of doing this!

2. The Method of Synthetic Division

If we abstract the long division process as much as possible we end up with what is called synthetic division. Lets look at an example and then we'll see how it can be converted to synthetic division.

Example 2.1:

> LongDiv( x^2 + 5*x + 2, -3 );

To divide synthetically ....
        we set it up in this way....create a table with the coefficients of the numerator along the top (right) and
        the root of the binomial divisor in the upper left corner.

        then we follow these steps :

                  BRING DOWN : bring down the leading coefficient ... all the way to the bottom

                  MULTIPLY UP : multiply the root (-3) by this number, and bring it up to 2nd row in the next column

we repeat these steps until we have finished the table and there is nothing left to bring down

> SynDiv( x^2 + 5*x + 2, -3 );

There are many things to notice about the bottom row of this table. If you compare it with the quotient and remainder we computed just above this, you'll see that the last entry in the bottom row is the remainder, and the other members of that row are the coefficients of the quotient. Of course the quotient has degree one less than the numerator since we are dividing by a binomial of degree one.

The advantages of this system are that its fast, easy, and less prone to errors. We merely need to read the answer off of the resulting last row to perform divisions.

Lets look at more examples.

Example 2.2:

> N := x^3 + 11*x^2 - 13*x + 8;
LongDiv( N, -5 );
SynDiv( N, -5 );

Example 2.3:

When we divide by a binomial like (x - 4), the root is +4.

> N := 4*x^3 + x^2 - 20*x + 3;
LongDiv( N , +4 );
SynDiv( N, +4 );

Example 2.4 :

Just as with long division, we need to remember to place zero terms as placeholders for any missing terms. That much is the same.

> N := 7*x^3 - 9*x + 11;
LongDiv( N , -2 );
SynDiv( N, -2 );

3. Synthetic Division In More Complicated Cases

This one is a little trickier ....

      Example 3.1 :

When dividing by a binomial with a coefficient in front of the x, we can use this trick ... factor that coefficient out. The quotient will be divided by that additional factor :

> print(4*x - 3 = 4,` * (`,x - 3/4,`)`);

> N := 4*x^3 - 9*x + 11;
SynDiv( N, +3/4 );

This is not the answer. We need to divide by 4.

> QQ := 4*x^2 + 3*x - 27/4; RR:= 95/16;

> QQ/4 + (RR)/(4*x -3);

> PolyDivide( N, 4*x - 3);

Notice that we only divide the quotient by 4. The remainder is undivided, so it stays as is.

Example 3.2 :

We use a similar trick on this problem - factor -1 out of the divisor to use synthetic division, then divide the quotient we get from synthetic division by -1.

> print(7 - x = -1,` * (`,x - 7,`)`);

> N := x^3 -4*x^2 -122;
SynDiv( N, +7 );

> QQ := x^2 + 3*x - 21; RR:= 25;

> QQ/(-1) + (RR)/(7-x);

> PolyDivide( N, 7 - x);

4. Finding Roots

Whenever we divide a polynomial by a binomial and the remainder is zero, that means the binomial divides into the polynomial. And thus the root of the binomial is a root of the polynomial.

> SynDiv( x^4 + x^3 + x^2 + x + 1, -1);

> SynDiv( 168*x^3+731*x^2-862*x+96, 6/7);

> SynDiv( 6*x^4-19*x^3-106*x^2+21*x+18, -3 );

> SynDiv( 6*x^4-19*x^3-106*x^2+21*x+18, -1/3 );