Partial Differential Equations PowerTool

by Dr. Jim Herod

Section 2.4: Calculus on Fourier Series

In the previous Section 2.3, we examined the nature of the convergence of series. Since we are going to be using representations of functions by their associated Fourier series to solve partial differential equations, we should pause a bit to ask if the derivative of a Fourier series representing f is a series which will represent the derivative of f . To see that this is a non-trivial question, recall that differentiation is a limiting process, as is integration. Also, forming an infinite series from the finite sums is a limiting process. So, to ask whether the derivative on an infinite sum be the sum of the derivatives is to ask whether the limits can be interchanged.

Example:  We show that the derivative of the series converging to f  is not the same as the series representing the derivative of f . We consider this example: take f ( x ) = x  on [-1, 1]. The Fourier Trigonometric Series must be a sine series since the function is odd.

>	L:=1; f:=x->x;

We compute coefficients for 20 terms.

>	for n from 1 to 20 do    a[n]:=int(f(x)*sin(n*Pi*x/L),x=-L..L)/int(sin(n*Pi*x/L)^2,x=-L..L): od:

Next, we define the approximation.

>	approx:=x->add(a[n]*sin(n*Pi*x/L),n=1..20): approx(x);

It is a good idea to check the approximation by comparing graphs.

>	plot([f(x),approx(x)],x=-1..1);

Maybe we can look at the coefficients and guess at the general formula. If not, we let Maple find the general formula.

>	n:='n':  assume(n,integer): a:=n->int(x*sin(n*Pi*x/L),x=-L..L)/int(sin(n*Pi*x/L)^2,x=-L..L): a(n);

Hence, the series could be written rather compactly as

Now, we differentiate the series term by term.

>	Sum(a(n)*diff(sin(n*Pi*x/L),x),n=1..20);

This series will not converge in norm, for the coefficients of this last are 2 . That is not a square summable sequence.

>

The question, then, is this: what additional hypothesis must there be so that the derivative of the series term by term converges the derivative of the function to which the series converged?  Here is the theorem.

THEOREM.  If f ( x ) is periodic, continuous, and sectionally smooth, then the differentiated Fourier series of f ( x ) converges to f  '( x ) at every point x  where f  ''( x ) exists.

The function in the previous example: f ( x ) = x  on the interval [-1, 1] did not have a continuous periodic extension. Thus, it did not satisfy the hypothesis of this Theorem.

Example:   An example that has a periodic extension that is continuous and sectionally smooth is   f ( x ) = | x | on [-1, 1]. The periodic extension has period 2 and is continuous. The extension is periodic, continuous, and sectionally smooth. We expect that the Fourier Series for f  to converge uniformly and that the differentiated series will converge at every point except possibly -1, 0, and 1. Look at the graphs.

>	f:=x->abs(x): f(x);

>	for n from 0 to 10 do    a[n]:=int(abs(x)*cos(n*Pi*x),x=-1..1)/int(cos(n*Pi*x)^2,x=-1..1): end do: n:='n':

>	approx:=x->add(a[n]*cos(n*Pi*x),n=0..10): approx(x);

>	plot([[x,f(x),x=-1..1],[x,approx(x),x=-3..3]], scaling=constrained);

We now plot both the derivative of f  and the derivative of the approximation for f .

>	plot([[x,diff(f(x),x),x=-1..1],[x,diff(approx(x),x),x=-3..3]]);

Perhaps these two examples give experimental evidence for some understanding for the nature of the results of the previous theorem and, second, make it believable. In both examples, do remember that outside the interval [-1, 1], we have that the series converges to the periodic extension of f ( x ).

What about integration?

THEOREM:  If f ( x ) is periodic and sectionally continuous, then the Fourier series for f ( x ) may be integrated term-by-term to provide an approximation for the integral of f ( x ).

Example:  We integrate over the interval [0, x ].

>

f(t);

>	int(f(t),t=-1..x); int(sum(a[n]*cos(n*Pi*t),n=0..5),t=-1..x);

>	plot([int(f(t)+0.01,t=-1..x),           int(sum(a[n]*cos(n*Pi*t),n=0..5),t=-1..x)],x=-1..1);

These two graphs are nearly the same! In fact, I have off-set the graph of f  by a little so that the graphs can be distinguished. This graph gives visual understanding to the results of the previous theorem.

This section has considered the issues involved with differentiating and integrating series term-by-term. We see that continuity of the periodic functions is an important condition for differentiability of Fourier Series. Not so much is need for the integration.

EMAIL: herod@math.gatech.edu   or    jherod@tds.net

URL: http://www.math.gatech.edu/~herod

Copyright ©  2003  by James V. Herod

All rights reserved