Calculus IV with Maple
Copyright 2002, Dr. Jack Wagner
j.wagner@intelligentsearch.com

Lesson 9: Surface Area

Topics: T he surface area is calculated five different ways including  the use of the first fundamental form,  the image of the coordinate plane under the map defining the surface and surfaces of rotation.

We compute the area of a surface by dividing it up into small parallelograms, and taking the limit of the sum of their areas as the parallelograms are made progressively smaller.  One way to look at this is to recognize that the area of a parallelogram of sides a  and b  with included angle , is .  Consider a surface known by a function,  .  The area of a small rectangle in the u-v plane is  .  The area of the image of this rectangle on the surface is

 , where   and   is the image of . Then,

 =  = | x |

and the limit of the Riemann  sum will be  .                                                                

Example 9.1

Find the area of the surface defined by:

,   { , }

>	restart: with(plots): with(LinearAlgebra): with(VectorCalculus):

>	f := <u, v, u^2-v^3>;

>	plot3d(f, u=-1..1, v=-1..1, axes=framed, color=blue, style=wireframe);

Maple's plotting function makes very concrete the idea of a surface composed of parallelograms that are the images of rectangles in the u-v plane.

>	df[u] := diff(f, u);

>	df[v] := diff(f, v);

>	areaElementVector := df[u] &x df[v];

>	dA := Norm( areaElementVector, 2 );

>	dA := simplify( dA ) assuming real;

>	int(int(dA, u=-1..1), v=-1..1);

If you attempt to explicitly integrate this expression, both you and Maple will fail.  Numerical evaluation is necessary.

>

evalf(%);

Example 9.2

Find the surface area of  , { , }

>	restart: with(plots): with(LinearAlgebra): with(VectorCalculus):

>	f := <u, v, sin(u)-cos(v)>;

>	plot3d(f, u=-1..1, v=-1..1, axes=framed, color=blue, style=wireframe, labels=[u, v, z]);

Now consider two vectors,  and     that form two sides of a parallelogram on a surface. Form a matrix with the vectors as columns.       Take the product,    =    =  

Compute the determinant of this product.  =  =

=  =  =    =  

Letting    and , this yields another formula for surface area.  where   is the Jacobian matrix of f .

Jacobian

>	J := Jacobian(f, [u, v, w]);

>	J := DeleteColumn(J, [3]);

>	S := Transpose(J).J;

>	Determinant(S);

>	Int(Int(sqrt(Determinant(S)), u=-1..1), v=-1..1);

>

evalf(%);

Now recollect  that the principal parts of the tangent vectors to a surface, , in the coordinate directions, are   and .  Also recollect the definitions; , , . Then, from

    =    , we obtain yet another formula for surface area,

  This is an important relation because the area is expressed in terms that are intrinsic  to the surface.

Example 9.3

Find the surface area defined by:     , ,

>	restart: with(plots): with(LinearAlgebra): with(VectorCalculus):

>	f := <u^2+v^2, sin(u), cos(v)>;

>	plot3d(f, u=0..Pi/2, v=0..Pi/2, axes=framed, color=blue, style=wireframe, labels=[u, v, z]);

>	df[u] := diff(f, u);

>	df[v] := diff(f, v);

>	E := df[u].df[u];

>	F := df[v].df[u];

>	G := df[v].df[v];

>	Int(Int(sqrt(E*G-F^2), u=0..Pi/2), v=0..Pi/2);

>

evalf(%);

Example 9.4

Consider the surface of revolution resulting from revolving the curve whose parametric equation is  , around the x axis.

We wish to calculate its surface area.

>	restart: with(plots): with(LinearAlgebra): with(VectorCalculus):

>	f := <x(t), y(t)>;

>	F := <f[1], f[2]*cos(theta), f[2]*sin(theta)>;

>	dF[t] := diff(F, t);

>	dF[theta] := diff(F, theta);

>	XP := dF[t] &x dF[theta];

>	Nsq := simplify(XP.XP, trig);

>	dA := sqrt(factor(Nsq), symbolic);

A very pretty result.  Continuing in the same spirit;

>	df[t] := diff(f, t);

>	ds := Norm(df[t], 2);

From which we conclude that  .  Therefore, we find the area as,

>	Area := Int(Int(y(t)*ds, t=a..b), theta=0..2*Pi);

>

value(%);

A result familiar from the calculus of a single variable.

Example 9. 5

Find the area of the surface formed by rotating the graph of    ,  

>	restart: with(plots): with(LinearAlgebra): with(VectorCalculus):

>	f := <sqrt(t)/(1+t), sin(t)>;

>	plot([f[1], f[2], t=0..10]);

Here we see one of Maple's advantages.  By plotting the curve before we start, we immediately know that there is a problem of self intersection when t>1.0.  To find the area of such a solid of rotation we need to break it up into simple (non self intersecting) surfaces.  We will separately compute the area of the surface formed by rotating the curve around the x axis from t=0 to t=1 and from t=1 to t=10.

>	plot([f[1], f[2], t=0..1]);

>	plot([f[1], f[2], t=1..10]);

>	F := [f[1], f[2]*cos(theta), f[2]*sin(theta)];

>	plot3d(F, t=0..10, theta=0..2*Pi, axes=normal, grid=[50,50], orientation=[80,60]);

>	df[t] := diff(f, t);

>	ds[t] := Norm(df[t], 2);

>	2*Pi*Int(f[2]*ds[t], t=0..1);

>	A[1] := evalf(%);

>	A[2] := evalf(2*Pi*Int(f[2]*ds[t], t=1..10));

>	Area := A[1]+A[2];

           From the equation, Area =   we may derive yet another expression for area.  Let a surface be known by an equation of the form,  or   

 =  =  =

Example 9. 6

>	restart: with(plots):with(LinearAlgebra): with(VectorCalculus):

>	Z := log(x+y);

>	p1 := implicitplot3d({x=.5, x=1.5, y=.5, y=1.5}, x=.5..1.5, y=.5..1.5, z= -1..1.5, axes=framed, color=red, style=wireframe):

>	p2 := plot3d(Z, x=0..2, y=0..2, axes=framed, labels=[x, y, z], color=blue):

>	display(p1, p2);

>	gZ := Gradient(Z, [x, y]);

>	dA := sqrt(1+gZ.gZ);

>	evalf(Int(Int(dA, y=.5..1.5), x=0.5..1.5));

We now have five expressions for surface area. Unfortunately, most surfaces yield integrals which are difficult or impossible to evaluate in closed or series form. Even numerical evaluation may be extraordinarily difficult. However, the use of the definition of the definite integral may succeed when all else fails. We construct upper and lower Riemann sums and examine a sequence of values for convergence.

Example 9.7

Find the area of the surface described by  f(x, y)=[sin(x), sin(y), sin(x+y)].

>	restart: with(plots): with(LinearAlgebra): with(VectorCalculus):

>	f := <sin(x), sin(y), sin(x+y)>;

>	plot3d(f, x=-Pi..Pi, y=-Pi..Pi, axes=framed, grid=[70,70], style=patchnogrid, lightmodel=light2);

>	J := Jacobian(f, [x, y, z]);

>	J := DeleteColumn(J, [3]);

>	dA := sqrt(Determinant(Transpose(J).J));

>	Int(Int(dA, x=0..2*Pi), y=0..2*Pi);

Maple has difficulty  integrating this expression or even producing a numerical answer.
First,  let's see what dA looks like.

>	plot3d(dA, x=0..2*Pi, y=0..2*Pi, axes=framed, color=aquamarine);

Noting the symmetry of the problem we need only evaluate the integral for , .    

We create Reimann sums using intervals over x and y of    where s increases from 1 to 8.  This gives a progression from 100 to 6400 cells, each with an area of   over which to evaluate and sum dA.  First the lower Reimann sums.

>	for s from 1 to 8 do   F := (k, t)->subs({x=k*Pi/(10*s), y=t*Pi/(10*s)}, dA):   A||s := evalf((Pi/(10*s))^2*sum(sum(F(p, q), p=0..10*s-1), q=0..10*s-1)):   print(A||s); end do:

           Now the upper Reimann sums.

>	for s from 1 to 8 do   F := (k, t)->subs({x=k*Pi/(10*s), y=t*Pi/(10*s)}, dA):   A||s := evalf((Pi/(10*s))^2*sum(sum(F(p, q), p=1..10*s), q=1..10*s)):   print(A||s) end do:

Convergence of both sequences to 7.43 seems apparent.

>	Area := 4*7.43;

Practice

1. Find the area of the plane defined by  enclosed in the elliptic cylinder over,
 .  

2. Find the area of the surface defined by  , that lies over the lozenge
 defined by:  

3. Find the area of the surface obtained by rotating, around the x axis, the curve
parametrized by:  

4. Find the area of the surface parametrized by   , and
enclosed in the unit sphere centered at the origin.

5. Find the surface area of the surface parameterized by:

     ,