Calculus IV with Maple
Copyright 2002, Dr. Jack Wagner
j.wagner@intelligentsearch.com

Lesson 7: Basic Differential Geometry of Surfaces

Topics: Tangents to a surface along coordinate curves.  Normal to a surface. The tangent plane. The first fundamental form. The length of a curve projected onto a surface.  Angle between vectors .

We begin by examining surfaces which we know as the graph of a map,  . These are most commonly of the form  .  We consider first, the partial derivatives of z at a given point, P. That is, the directional derivatives of z with respect to each variable.  We will then find the tangents to the surface in the direction of each of the variables; the coordinate directions.  

Example 7.1

>	restart: with(plots): with(LinearAlgebra): with(VectorCalculus):

>	f := <x, y, sin(x*y)>;

The point P on the surface.

>	p1 := eval(f, {x=Pi/4, y=Pi/4});

We compute the principal parts of the tangent vectors in the coordinate directions.

>	df[x] := diff(f, x);

>	dfx[x, y=Pi/4] := eval(df[x], {x=Pi/4, y=Pi/4});

>	df[y] := diff(f, y);

>	dfy[x, y=Pi/4] := eval(df[y], {x=Pi/4, y=Pi/4});

Now normalize each of these tangent vectors.

>	t[1] := Normalize(dfx[x, y=Pi/4], 2);

>	t[2] := Normalize(dfy[x, y=Pi/4], 2);

It is not necessary to normalize for the purpose of drawing the tangent line, but we will need the unit tangent vectors later. Now we create the tangent line equations.

>	T[1] := p1+s*t[1]:

>	T[2] := p1+s*t[2]:

" spacecurve " will only accept lists as an argument.

>	TL[1] := convert(T[1], list): TL[2] := convert(T[2], list):

>	P1 := spacecurve({TL[1], TL[2]}, s=-1..1, thickness=3, color=black):

>	P2 := plot3d(f, x=0..Pi/2, y=0..Pi/2, color=pink):

>	display(P1, P2, axes=boxed, orientation=[-40, 40]);

Here we have a pair of tangents lying in the direction of the coordinate lines on the surface. These are really the images  of the x any y axes with the origin transported to P.

Now we add a normal line.  Remember that the cross product of two vectors is orthogonal to the plane in which they lie and oriented according to the right hand rule.

>	n := t[1] &x t[2];

We work with the unit normal.

>	n := Normalize(n);

Now create the equation for the normal line

>	N := p1+s*n:

>	NL := convert(N, list):

>	P3 := spacecurve({TL[1], TL[2], NL}, s=-1..1, thickness=3, color=black):

>	display(P1, P2, P3, axes=boxed, orientation=[-25,60]);

Now we have a set of unit vectors, {t1, t2, n},  which can be used as the basis for a coordinate system to investigate phenomena occurring on or near the surface in the neighborhood of the point, P= ( ).

We do this in our daily lives.  We do not ordinarily refer our motion to spherical coordinates, but rather North, South, East, West up and down.  The tangents we have found, however, are not orthogonal!

Anticipating a result,    where  is the angle between  and . Remembering that  and  are unit tangent vectors:

>	theta[rad] := evalf(arccos(t[1].t[2]));

>	theta[deg] := evalf(convert(theta[rad], degrees));

It is also a simple matter to define a tangent plane at a point.  We compute the equation of the tangent plane orthogonal to the normal at P.

>	r := <x,y,z>:

>	TP1 := (r-p1).n=0;

Represent the tangent plane as an explicit function  by solving for z

>	TP := solve(TP1, z);

>	P4 := plot3d(TP, x=0..2, y=0..2, color=blue, style=wireframe):

>	P5 := spacecurve(NL, s=-1..1, thickness=3, color=black):

>	display(P2, P4, P5, axes=boxed, orientation=[150,70]);

It turns out to be more fruitful to define the tangent plane in terms of the two tangent vectors,  and .

>	TP2 := p1+s*t[1]+t*t[2]:

>	P6 := plot3d(TP2, s=-1..1, t=-1..1, color=blue, style=wireframe):

>	display(P1, P2, P6, axes=framed, orientation=[150,70]);

This is a useful exercise because, just as the tangent at a point on a curve is an approximation to the curve in a neighborhood of the  point, so the tangent plane at a point on a surface is an approximation to the surface in a neighborhood of the point. The set of vectors, {t1 t2, n},  form a  convenient set of axes to which events on the surface may be referred.  Thus, given a surface defined by:  

                      
and a curve on that surface parametrized by t: ,  consider a tangent vector, V, to the curve at a point  : u' ( )  + v'( ),  where  and    u' ( )=  and similarly for v.  Now, V lies in the tangent plane which has as its coordinate basis,  and  and has components in that basis, u' ( ), v'( ) . The quadratic form, defined by the inner product  on  , =   and expressed in the ,  basis is known as the first fundamental form.

=  = < u' ( )  + v'( ), u' ( )  + v'( )> =  + 2        +

 Traditionally one sets:                                     
In these terms we have:   =    =    + 2        +    

             We have expressed the element of arc length, ds ,  in terms that are intrinsic to the surface.  Many other properties of the surface can also be expressed in terms of these intrinsic quantities.  As an example, the angle between the two coordinate tangent vectors,  and     at  p, is found by:  = .  The coordinate vectors are orthogonal if and only if F =0.

Example 7.2

Compute the arc length of the curve  projected onto the surface

>	restart: with(plots): with(LinearAlgebra): with(VectorCalculus):

>	f := <x, y, sin(x*y)>;

>	u := t:  v := t^2:

The parabola  in the x-y plane.

>	C1 := <u, v, 0>;

The parabola projected onto the surface

>	C2 := eval(f, {x=u, y=v});

Now we create plot structures for the surface, the parabola in the x-y plane and the parabola projected onto the surface.

>	C1L := convert(C1, list): C2L := convert(C2, list):

>	P1 := plot3d(f, x=0..Pi/2, y=0..Pi/2, color=pink, style=wireframe):

>	S1 := spacecurve(C1L, t=0..1.2, color=blue, thickness=3):

>	S2 := spacecurve(C2L, t=0..1.2, color=red, thickness=3):

>	display(S1, S2, P1, axes=boxed, labels=[x, y, z], orientation=[160,60]);

Now we compute the coefficients of the first fundamental form.

>	df[x] := diff(f, x);  df[y] := diff(f, y);

>	E := df[x].df[x];

>	F := df[x].df[y];

>	G := df[y].df[y];

Now the derivatives of  and ..

>	du := diff(u, t);

>	dv := diff(v, t);

Now we compute the element of arc length in terms of the coefficients of the first fundamental form.

>	ds := sqrt(E*du^2+2*F*du*dv+G*dv^2);

>	ds[u, v] := subs({x=t, y=t^2}, ds);

            Compute the arc length of the curve between t=0 and t=1.

>	arclength := evalf(int(ds[u, v], t=0..1));

Once the methodology is in place it is a simple matter to call up the saved worksheet and replace the surface, the curve and the parameter limits.

Example  6.3

Project the plane curve,   onto the surface,  , and find its length, on the surface, between  and .

>	restart: with(plots): with(LinearAlgebra): with(VectorCalculus):

The surface

>	f := <x, y, log(x+y)>:

>	u := t:    v := sin(2*t):

The curve in the plane defined parametrically

>	C1 := <u, v, 0>:

The curve embedded in the surface

>	C2 := subs({x=u, y=v}, f):

>	P1 := plot3d(f, x=0..Pi/2, y=0..Pi/2, color=pink, style=wireframe):

>	S1 := spacecurve(evalm(C1), t=0..Pi/2, color=blue, thickness=3):

>	S2 := spacecurve(evalm(C2), t=0..Pi/2, color=red, thickness=3):

>	display(S1, S2, P1, axes=framed, labels=[x, y, z]);

>	df[x] := diff(f, x); df[y] := diff(f, y);

>	E := df[x].df[x];

>	F := df[x].df[y];

>	G := df[y].df[y];

>	du := diff(u, t);

>	dv := diff(v, t);

>	ds[1] := sqrt(E*du^2+2*F*du*dv+G*dv^2);

>	ds[2] := subs({x=t, y=sin(t)}, ds[1]);

>	arclength := evalf(int(ds[2], t=Pi/4..Pi/2));

Note that, in creating a composite plot from separate plot structures, options specific to each plot such as the color and thickness are specified for each plot structure, while options such as the style of axes and labeling are specified in the display command.  

Example 7.4

If we were interested in working at a point on the surface of Ex. 7.3,  say ,  we would like to have a coordinate system with origin at P, and with axes tangent to the surface.  Proceeding as before:

>	P := eval(f, {x=u, y=v});

>	P := eval(P, t=Pi/4);

>	v1 := eval(df[x], {x=u, y=v});

>	v1 := eval(v1, t=Pi/4);

>	v1 := Normalize(v1, 2, inplace);

>	v2 := eval(df[y], {x=u, y=v});

>	v2 := subs(t=Pi/4, v2);

>	v2 := Normalize(v2, 2, inplace);

>	ax1 := P+s*v1;  ax2 := P+s*v2;

>	S4 := spacecurve({evalm(ax1), evalm(ax2)}, s=-1..1, color=black, thickness=3):

>	display(P1, S2, S4, axes=framed, labels=[x, y, z]);

>	theta := evalf(arccos(v1.v2));

>	theta := evalf(convert(theta, degrees));

In courses on differential geometry the equations for curves, imbedded in a surface, are derived with respect to such coordinate systems.

Practice
1. Plot the surface,   together with coordinate tangent lines, normal line and tangent plane at the point    .
2. For the surface defined by   ,  find the gradient at the point (5, -5) and the plane orthogonal to the gradient through the point, (5, -5, 6.299605249).
3. Project the curve,   onto the surface  ,  between the points  , and find the length of the projected curve, between  and .  Plot the curve, and its projection together with the surface.
4. Project the straight line, y=3x onto the surface   , and plot them both on the same set of axes in the range   .  Find the length of the projected line.