Calculus IV with Maple
Copyright 2002, Dr. Jack Wagner
j.wagner@intelligentsearch.com

Lesson 10: Surface Integrals

Topics: Integration over a surface.  Integrating over the Moebius band.

Maple commands introduced:   stackmatrix, augment

In the same way that a vector field may be integrated over a curve, it may be integrated over a surface.  To each parallelogram that forms an element of the area of the surface we assign the normal component of the vector field at some interior point.  As the partition of the surface is refined  the sum of the products of the area of the parallelograms and the normal component of the vector field is the integral of the vector field over the surface, usually written,   , where S is the surface, or , where dA is understood to represent the "element of area", n is the unit normal and U is the  parameterization.  This integral is the flux of F through the surface S. Because the normal to the surface plays a key role it is important that we work only with surfaces over which it is possible to consistently define a unit normal.  That is, there must be a vector valued function, n (p), that assigns a unique unit normal to each point, p. Such a surface is orientable.

The archetypical non-orientable surface is the Moebius band, which may be parameterized and plotted as follows.

>	restart: with(plots):with(LinearAlgebra): with(VectorCalculus):

>	F := <(2-v*sin(u/2))*sin(u), (2-v*sin(u/2))*cos(u), v*cos(u/2)>;

>	plot3d(F, u=-Pi..Pi, v=-1..1, axes=framed, style=wireframe);

It is not orientable because at each point the "function"  n(v, u),  creates two unit normals  each pointing in the opposite direction. For a surface   define  .

If we plot n (u, v) over a surface, we expect to get a copy of the original surface one unit away.  For the Moebius band, however:

>	dF[u] := diff(F, u);

>	dF[v] := diff(F, v);

>	n := dF[v] &x dF[u]:

>	N := Normalize(n, 2, inplace):

>	P1 := plot3d(F+N, u=-2*Pi..2*Pi, v= -1..1, axes=framed, style=wireframe, color=blue, grid=[40,40]):

>	P2 := plot3d(F, u=-Pi..Pi, v=-1..1, axes=framed, color=pink):

>	display({P1, P2}, scaling=constrained, orientation=[-135,75]);

At each point on the surface u(v, u) has created two unit normals and therefore it is not well defined on this surface.  A bit further on we will look at how non-orientability interferes with integration of a vector field over a surface.  We are also going to confine ourselves to simple surfaces, that is, surfaces which do not contain singularities such as self intersections.

Let F be the vector field. The unit normal to the surface S, known by , is  

 . We already know that   dudv  .  Therefore,  =  =

Example 10.1

Find the flux of   through the surface of the paraboloid    ,

>	restart: with(plots): with(LinearAlgebra): with(VectorCalculus):

>	F := <1/x^2, 1/y^2, 1/z^2>;

Now select a parametrizarion for S. {x=u, y=v}

>	S := <u, v, u^2+v^2>;

>	F := eval(F, {x=S[1], y=S[2], z=S[3]});

>	P1 := plot3d(S, u=1..3, v=1..3, color=aquamarine, style=wireframe, axes=framed):

>	P2 := fieldplot3d(F, u=1..3, v=1..3, z=1..18, arrows=THICK, grid=[5, 5, 5], color=black):

>	display(P1, P2);

Now we compute.

>	dS[u] := diff(S, u);

>	dS[v] := diff(S, v);

>	n := dS[v] &x dS[u];

Note that we have selected the "outward" pointing normal.

>	FdA := F.n;

The flux over the surface is

>	int(int(FdA, u=1..3), v=1..3);

Or numerically,

>

evalf(%);

In the standard basis, { i, j, k },  where the subscripts indicate the derivative.  This can be evaluated as   i  - j  + k    . Therefore,   F dA =

 which yields  =  

Example 10.2

Integrate    over the surface defined by   , ,

>	restart: with(plots): with(LinearAlgebra): with(VectorCalculus):with(linalg):

>	F := <x^2, y^2, z^2>;

>	S := <u, v, sin(u+v)>;

>	F := eval(F, {x=S[1], y=S[2], z=S[3]});

>	dS[u] := diff(S, u);

>	dS[v] := diff(S, v);

>	FdA := <<F>|<dS[u]>|<dS[v]>>;

>	Int(Int(Determinant(FdA), u=0..Pi), v=0..Pi);

>

value(%);

The determinant formulation leads to the following interpretation.  Consider the first term in the expansion of the determinant in minors of the first row.      -      +      .      is the component of F in the x-y plane,    . is the area of the projection, onto the x-y plane,  of the element of area on the surface of S.  Similarly for the other two components, except that the x-z plane projection has a negative sign.  (Rotate the basis vector of the x axis into the z axis basis vector and, by the right hand rule, you will find that the resulting vector has an opposite sense to that of the y axis.)  The sum of these projections is precisely the determinant given.

From the basic definition of the surface integral, i.e.  we also obtain
 =  

Example 10.3

Compute the integral of  over the surface,  ,    ,  

>	restart:with(plots):with(LinearAlgebra): with(VectorCalculus):

>	f := <x, 2^y, 2^(-y)>;

>	S := <x, y, -2*x-3*y>;

>	P1 := plot3d(S, x=0..1, y=0..1, color=blue, style=wireframe):

>	P2 := fieldplot3d(f, x=0..1, y=0..1, z=-6..1, color=red, grid=[5, 5, 5], thickness=2):

>	display(P1, P2, axes=normal );

For a plane whose equation is 3x-2y-z=0, we know that  [3, -2, -1] is the principal part of a normal vector at every point.

>	N := <3, 2, 1>;

>	n := Normalize(N, 2, inplace);

>	s[x] := diff(S, x);

>	s[y] := diff(S, y);

>	E := s[x].s[x];

>	F := s[x].s[y];

>	G := s[y].s[y];

>	sqrt(E*G-F^2);

>	FdA := f.n*sqrt(E*G-F^2);

>	Int(Int(FdA, x=0..1), y=0..1);

>

value(%);

>

evalf(%);

Now let's look at what happens when we try to integrate a function over the surface of a Moebius band.

Example 10.4

Calculate the integral of

>	restart: with(plots): with(LinearAlgebra): with(VectorCalculus):

>	S := <(2-v*sin(u/2))*sin(u), (2-v*sin(u/2))*cos(u), v*cos(u/2)>;

>	F := <u^2+v, v^2+u, sin(u+v)>;

>	dS[u] := diff(S, u);

>	dS[v] := diff(S, v);

>	FdA := <<dS[u]>|<dS[v]>|<F>>;

Now we integrate over the surface of the Moebius band.  First in a positive and then in a negative direction.  The results should sum to zero.  They do not!

>	int(int(Determinant(FdA), u=0..2*Pi), v=-1..1);

>	int(int(Determinant(FdA), u=0..-2*Pi), v=-1..1);

>

%+%%;

The surface integral of F computes the volume of a solid whose base is the surface and whose height is the normal projection of F.   If F happens to be the unit normal, then    = Area.

Practice

1.       Compute the indicated surface integrals.
           a)    ,  , x=0..1,  y=0..

           b)    ,  ,  x=-6..6, y=0..

           c)    , S(x, y) = {x, y, z|  },  { x, y }|    

2.       Using Maple, show that for a vector field, F, symmetrical around the axis of revolution, the surface integral over a surface of revolution, between   and ,  is  , where   is the vector field component along the axis of revolution and    is the area of the surface disc at  .